1 REM      VERGL.VON PRG.
10 :
20 REM *************************
30 REM *                       *
40 REM *  GERHARD REUL         *
50 REM *  8591 TROESTAU        *
60 REM *  TEL. 09232/1678      *
70 REM *                       *
80 REM *************************
90 :
100 DIM X(256),Y(256):Z1$="......"
110 F1$="<> ZEILEN-LAENGE":F2$="ZEICHEN-FEHLER":F3$="<> ZEILEN-NR.!!!"
120 GOTO450
130 OPEN15,8,15,"I"
140 OPEN2,8,2,B1$+",P,R":F=1:GOSUB590
150 OPEN3,8,3,B2$+",P,R":F=2:GOSUB590
160 GET#2,X$,X$
170 GET#3,X$,X$
180 REM======= LADEN PRG 1 =============
190 GET#2,X$:IFX$=""THENX$=CHR$(0)
200 I=I+1:X(I)=ASC(X$)
210 REM (ZU ZEILE 220)  ZEILEN-NR. BESTIMMEN
220 IFI=4THENZ=X(4)*256+X(3):Z$=RIGHT$(Z1$+STR$(Z),7):PRINT"     ZEILE"Z$"  OK[145]"
230 IFX(I)=0THEN GOTO260
240 GOTO190
250 REM  ZEILEN-ODER PRG.-ENDE BESTIMMEN
260 IFI=2THEN:IFX(1)=0ANDX(2)=0THENCLOSE2:CLOSE3:CLOSE15:GOTO550:REM  PRG.-ENDE
270 IFI<5THENGOTO190
280 II=I:I=0
290 REM======= LADEN PRG 2 =============
300 GET#3,Y$:IFY$=""THENY$=CHR$(0)
310 J=J+1:Y(J)=ASC(Y$)
320 IFY(J)=0THEN GOTO340
330 GOTO300
340 IFJ<5THENGOTO300
350 JJ=J:J=0
360 REM====== VERGLEICHEN ==============
370 IFX(3)<>Y(3)ORX(4)<>Y(4)THEN:F$=F3$:GOSUB420:GOTO430
380 IFII<>JJTHEN:F$=F1$:GOSUB420:GOTO190
390 FORI=5TOII
400 IFX(I)<>Y(I)THEN:F$=F2$:GOSUB420:I=II
410 NEXT:I=0:GOTO190
420 PRINT""F$:RETURN
430 PRINT"         BITTE UEBERPRUEFEN !    [146]":CLOSE2:CLOSE3:CLOSE15:GOTO560
440 REM========= MENUE =================
450 PRINT"[147]       VERGLEICHEN VON PROGRAMMEN [146]"
460 PRINT"  ES KOENNEN ZWEI BASIC-PROGRAMME,"
470 PRINT"  DIE SICH AUF EINER DISKETTE BEFINDEN,"
480 PRINT"  MITEINANDER VERGLICHEN WERDEN."
490 INPUT"   PROGRAMM-NAME 1 ";B1$:PRINT:PRINT
500 INPUT"   PROGRAMM-NAME 2 ";B2$
510 PRINT"[147]      VERGLEICHEN VON PROGRAMMEN [146]"
520 PRINT"  PROGRAMM 1:         PROGRAMM 2:"
530 PRINT"  "B1$"                "B2$"":GOTO130
540 REM========== WARTEN ===============
550 PRINT"              ENDE "
560 GETA$:IFA$=""THEN560
570 RUN
580 REM====== FEHLER-KANAL =============
590 INPUT#15,A,A$:IFA=0THENRETURN
600 PRINT"   "F"[157]. ";A$:CLOSE2:CLOSE3:CLOSE15
610 GOTO560